1. 常用命令

:: 定时什么时候关机
at 23:00 shutdown -s
:: 定时多少秒后关机 
shutdown -s -t 1800
:: 取消关机
shutdown -a

Win + R 打开内置程序

:: 打开远程桌面链接工具
mstsc
:: 安装硬件
hdwwiz
:: 添加一个新设备
devicepairingwizard
:: 打开授权管理器
azman.msc
:: 打开用户账户窗口
netplwiz
:: 打开备份和恢复
sdclt
:: 计算器
calc
:: 打开用户证书窗口
certmgr.msc
::字符集映射表
charmap
:: 打开clear type 文本调揩器
cttune
:: 命令行窗口
cmd
:: 组件服务
comexp.msc/dcomcnfg
:: 查看电脑使用记录
recent

:: 查看指定端口
netstat -aon|findstr "port"
:: 查看PID对应的程序
tasklist|findstr "PID"
:: 杀死程序
taskkill /f /t /im tor.exe
:: 杀死指定PID线程
taskkill /pid 2472 -t -f; 

2. 添加右键菜单

1. 手动添加

win + r 执行 regedit

• 自定义程序右键菜单

打开注册表路径
HKEY_CLASSES_ROOT\Directory\Background\shell
在shell新建文件目录（以程序名命名）, 并创建 icon 字符串项，指定图标路径，可以是QQ.exe
接着在新建目录下创建 command项，设置为字符串值，指定为运行的文件的路径程序，如QQ.exe

• 创建word的doc格式 右键菜单：HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew ，在ShellNew下新建**FileName（字符串类型）**并指定字符串值为**word.doc**
• 创建excel的xls格式 右键菜单: HKEY_CLASSES_ROOT\.xls\Excel.Sheet.8\ShellNew， 在ShellNew下新建**FileName（字符串类型）**并指定字符串值为**excel.xls**
• 创ppt的ppt格式 右键菜单: HKEY_CLASSES_ROOT\.ppt\PowerPoint.Show.8\ShellNew，在ShellNew下新建**FileName（字符串类型）**并指定字符串值为**PowerPoint.ppt**
• 创建visio的vsd格式 右键菜单: HKEY_CLASSES_ROOT\.vsd\Visio.Drawing.11\ShellNew，在ShellNew下新建**FileName（字符串类型）**并指定字符串值为**visio.vsd**

2. 脚本添加

@ECHO OFF
title 添加右键菜单脚本
:: @ECHO OFF & PUSHD %~DP0 & TITLE
>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
    Exit /b
)

:Start
@ECHO 操作，输入a:新增；r:删除;其他:退出
SET /P OP=
if "%OP%"=="a" (
 @ECHO 输入菜单名称
 SET /P NAME=
 @ECHO 输入程序绝对路径
 SET /P ADDR=
 goto Add 
) else if "%OP%"=="r" (
 @ECHO 输入菜单名称
 SET /P NAME=
 goto Remove 
) else (
pause
)

:Add
reg add "HKEY_CLASSES_ROOT\*\shell\%NAME%"         /t REG_SZ /v "" /d "%NAME%"   /f
reg add "HKEY_CLASSES_ROOT\*\shell\%NAME%"         /t REG_EXPAND_SZ /v "Icon" /d "%ADDR%" /f
reg add "HKEY_CLASSES_ROOT\*\shell\%NAME%\command" /t REG_SZ /v "" /d "%ADDR% \"%%1\"" /f

reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\%NAME%"         /t REG_SZ /v "" /d "%NAME%"   /f
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\%NAME%"         /t REG_EXPAND_SZ /v "Icon" /d "%ADDR%" /f
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\%NAME%\command" /t REG_SZ /v "" /d "%ADDR%" /f
goto Start

:Remove
reg delete "HKEY_CLASSES_ROOT\*\shell\%NAME%" /f
reg delete "HKEY_CLASSES_ROOT\Directory\Background\shell\%NAME%" /f
goto Start

3. 绿色软件添加

以EmEditor193为例，EmEditor193为程序文件夹名称，%~dp0EmEditor.exe为运行的执行程序，当然通过手动脚本添加也可以。

@ECHO OFF & PUSHD %~DP0 & TITLE
>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
    Exit /b
)
SET /P ST=输入a添加右键菜单，输入r删除右键菜单：
if /I "%ST%"=="a" goto Add
if /I "%ST%"=="r" goto Remove

:Add
reg add "HKEY_CLASSES_ROOT\*\shell\EmEditor193"         /t REG_SZ /v "" /d "Open &EmEditor193"   /f
reg add "HKEY_CLASSES_ROOT\*\shell\EmEditor193"         /t REG_EXPAND_SZ /v "Icon" /d "%~dp0EmEditor.exe" /f
reg add "HKEY_CLASSES_ROOT\*\shell\EmEditor193\command" /t REG_SZ /v "" /d "%~dp0EmEditor.exe \"%%1\"" /f

reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\EmEditor193"         /t REG_SZ /v "" /d "Open &EmEditor193"   /f
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\EmEditor193"         /t REG_EXPAND_SZ /v "Icon" /d "%~dp0EmEditor.exe" /f
reg add "HKEY_CLASSES_ROOT\Directory\Background\shell\EmEditor193\command" /t REG_SZ /v "" /d "%~dp0EmEditor.exe" /f
exit

:Remove
reg delete "HKEY_CLASSES_ROOT\*\shell\EmEditor193" /f
reg delete "HKEY_CLASSES_ROOT\Directory\Background\shell\EmEditor193" /f
exit